This demo illustrates how you can use Flex, PureMVC and Adobe AIR local SQL database to create simple member management system. With the Member Database you can store unlimited number of members, sort any information in the database and export data to xml file.

Sample Files:
MemberDatabase.zip (ZIP, 647 KB)

This AIR application demonstrates how to download, pause and resume downloads of larger files(mp3, flv, etc) and save to the user’s computer. Big Thanks to Benjamin Dobler for his blog post Resumable Downloads with AIR.

Sample Files:
ResumableDownloader.air (AIR, 524 KB)

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute"
    creationComplete="init()" viewSourceURL="srcview/index.html"> 

    <mx:Script>
        <![CDATA[
            private function init():void
            {
                nativeApplication.idleThreshold = 20;
                nativeApplication.addEventListener(Event.USER_IDLE, userIdleHandler);
                nativeApplication.addEventListener(Event.USER_PRESENT, userPresentHandler);
            } 

            private function userIdleHandler(event:Event):void
            {
                trace('idle');
            } 

            private function userPresentHandler(event:Event):void
            {
                trace('present');
            }
        ]]>
    </mx:Script> 

</mx:WindowedApplication>

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute"> 

    <mx:Script>
        <![CDATA[
            import mx.core.Application;
            import mx.core.Window;

            private function openPopupWindow():void
            {
                var alertWindow:Window = new Window();
                alertWindow.title = 'Alert Window';
                alertWindow.width = 400;
                alertWindow.height = 200;
                alertWindow.open();

                centerWindow(alertWindow);
            } 

            private function centerWindow(window:Window):void
            {
                var screenBounds:Rectangle = Screen.mainScreen.bounds;
                var nativeWindow:NativeWindow = window.nativeWindow;

                var mainNativeWindow:NativeWindow = Application.application.nativeWindow;
                for each(var screen:Screen in Screen.screens.reverse())
                {
                    if(mainNativeWindow.x > screen.bounds.x)
                    {
                        nativeWindow.x = mainNativeWindow.x +
                                             (mainNativeWindow.width - nativeWindow.width)/2;
                        nativeWindow.y = mainNativeWindow.y +
                                             (mainNativeWindow.height - nativeWindow.height)/2;
                    }
                    else
                    {
                        nativeWindow.x = (mainNativeWindow.width - nativeWindow.width)/2;
                        nativeWindow.y = (mainNativeWindow.height - nativeWindow.height)/2;
                    }
                } 

                nativeWindow.x = (screenBounds.width - nativeWindow.width)/2;
                nativeWindow.y = (screenBounds.height - nativeWindow.height)/2;
            }
        ]]>
    </mx:Script>
    <mx:Button x="10" y="10" label="Open popup window"
        click="openPopupWindow()"/> 

</mx:WindowedApplication>

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute"
    creationComplete="centerWindow(this)" viewSourceURL="srcview/index.html"> 

    <mx:Script>
        <![CDATA[
            import mx.core.Window;

            private function centerWindow(window:WindowedApplication):void
            {
                var screenBounds:Rectangle = Screen.mainScreen.bounds;
                var nativeWindow:NativeWindow  = window.nativeWindow;

                nativeWindow.x = (screenBounds.width - nativeWindow.width)/2;
                nativeWindow.y = (screenBounds.height - nativeWindow.height)/2;
            }
        ]]>
    </mx:Script> 

</mx:WindowedApplication>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute"
    creationComplete="init()" viewSourceURL="srcview/index.html"> 

    <mx:Script>
        <![CDATA[
            private var _air:Object;
            private var _applicationID:String = 'YOUR_APP_ID';
            private var _publisherID:String = 'YOUR_PUBLISHER_ID';
            private var _arguments:String;

            [Bindable]
            private var _output:String = '';

            private const AIR_DETECTION_URL:String =
                'http://airdownload.adobe.com/air/browserapi/air.swf';

            private function init():void
            {
                _output += 'Detecting AIR Installation...n';

                var loader:Loader = new Loader();
                var loaderContext:LoaderContext = new LoaderContext();
                loaderContext.applicationDomain = ApplicationDomain.currentDomain;
                loader.contentLoaderInfo.addEventListener(Event.INIT, onInit);

                loader.load(new URLRequest(AIR_DETECTION_URL), loaderContext);
            } 

            private function onInit(event:Event):void
            {
                _air = event.target.content;
                switch(_air.getStatus())
                {
                    case "installed" :
                        // AIR is installed and has been detected
                        _output += 'SUCCESS: AIR installation detectedn';
                        stage.addEventListener(MouseEvent.CLICK, onButtonClicked);
                        break;
                    case "available" :
                        // AIR is Available
                        _output += 'SUCCESS: AIR is availablen';
                        break;
                    case "unavailable" :
                        // AIR Not Available
                        _output += 'FAILURE: AIR not available';
                        break;
                }
            } 

            private function onButtonClicked(event:MouseEvent):void
            {
                _air.launchApplication(_applicationID,_publisherID,_arguments);
            }
        ]]>
    </mx:Script>
    <mx:TextArea x="10" y="10" height="178" borderStyle="solid" borderColor="#67696A"
        text="{_output}" width="255"/> 

</mx:Application>

Launch Demo

Useful links:
http://www.davidtucker.net/2008/01/11/air-tip-6-launching-an-application-from-the-browser/

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml"
    layout="absolute" xmlns:local="*" width="300" height="200" viewSourceURL="srcview/index.html"> 

    <mx:Script>
        <![CDATA[
            import mx.core.UIComponent;

            private var dragItem:UIComponent;
            private var dragImg:Image;

            private function startNativeDrag(event:MouseEvent):void
            {
                dragItem = UIComponent(event.currentTarget);
                var bitmapFile:File = File.applicationDirectory;
                bitmapFile = bitmapFile.resolvePath('air_icon.png');

                var offset:Point = new Point(-event.localX, -event.localY);

                var clip:Clipboard = new Clipboard();
                clip.setData(ClipboardFormats.FILE_LIST_FORMAT, [bitmapFile]);

                var bd:BitmapData = new BitmapData(dragItem.width, dragItem.height);
                bd.draw(dragItem);

                var dragOptions:NativeDragOptions = new NativeDragOptions();
                dragOptions.allowCopy = true;
                dragOptions.allowLink = true;
                dragOptions.allowMove = false;

                dragItem.addEventListener(NativeDragEvent.NATIVE_DRAG_COMPLETE, stopNativeDrag);
                NativeDragManager.doDrag(dragItem, clip, bd, offset, dragOptions);
            } 

            private function stopNativeDrag(event:NativeDragEvent):void
            {
                dragItem.removeEventListener(NativeDragEvent.NATIVE_DRAG_COMPLETE, stopNativeDrag);
            }
        ]]>
    </mx:Script> 

    <mx:Image id="img"
        x="83" y="41"
        source="air_icon.png"
        width="98" height="98"
        mouseDown="startNativeDrag(event)"/> 

</mx:WindowedApplication>