This application demonstrates how to use AIR 2.0 Native Process with Java program. Air application sends String to Java program, Java program reads it and sends back to AIR app. Before packaging the ‘NativeProcessDemo’ application into an AIR file, make sure you have added the following line to application description file <supportedProfiles>extendedDesktop desktop</supportedProfiles>. Next, use command line tool to package an AIR app in a native installer.

Sample Files:
NativeProcessDemo.mxml (MXML, 12 KB),
HelloWorld.java (JAVA, 1 KB)

Related Topics:

• Creating an AIR application using the command line tools
• Interacting with a native process
• Adobe Air to Exe – Packaging Air app in Windows executable
• Packaging an AIR application in a native installer
• Your First AIR 2.0 EXE file
• Adobe Flex & Air – packaging Air app in native install

ContactMessage.as

package com.mariusht.contactmanager.common.messages
{
    import com.mariusht.contactmanager.common.model.vo.ContactVO;

    import org.puremvc.as3.multicore.utilities.pipes.messages.Message;

    public class ContactMessage extends Message
    {
        protected static const NAME:String = 'ContactMessage';

        public static const ADD_CONTACT:String = NAME + '/message/contact/add';
        public static const CONTACT_ADDED:String = NAME + '/message/contact/added';
        public static const CONTACT_ADD_FAILED:String = NAME + '/message/contact/add/failed';

        public static const UPDATE_CONTACT:String = NAME + '/message/contact/update';
        public static const CONTACT_UPDATED:String = NAME + '/message/contact/updated';
        public static const CONTACT_UPDATE_FAILED:String = NAME + '/message/contact/update/failed';

        public static const REMOVE_CONTACT:String = NAME + '/message/contact/remove';
        public static const CONTACT_REMOVED:String = NAME + '/message/contact/removed';
        public static const CONTACT_REMOVE_FAILED:String = NAME + '/message/contact/remove/failed';

        public function ContactMessage(type:String, contact:ContactVO=nulll)
        {
            // add headers if needed
            super(type, null, contact);
        } 

        public function get contact():ContactVO
        {
            return body as ContactVO;
        }
    }
}

JunctionMediator.as

...
override public function handlePipeMessage(message:IPipeMessage):void
{
    switch(message.getType())
    {
        case ScreenMessage.GET:
            //
            break;
        case ContactMessage.CONTACT_ADDED:
            contactsProxy.addContact( ContactMessage(message).contact );
            break;
        case ContactMessage.CONTACT_UPDATED:
            contactsProxy.updateContact( ContactMessage(message).contact );
            break;
        case ContactMessage.CONTACT_REMOVED:
            contactsProxy.removeContact( ContactMessage(message).contact );
            break;
        case ItemMessage.ITEM_ADDED:
            itemsProxy.addItem( ItemMessage(message).item );
            break;
        case ItemMessage.ITEM_UPDATED:
            itemsProxy.updateItem( ItemMessage(message).item );
            break;
        case ItemMessage.ITEM_REMOVED:
            itemsProxy.removeItem( ItemMessage(message).item );
            break;
    }
}
...

// load the update-descriptor
var loader:URLLoader = new URLLoader;
loader.addEventListener(Event.COMPLETE, onLoadComplete);
loader.load(new URLRequest('http://mariusht.com/files/products/notelist/update.xml'));

2. Check and see if a user has the latest version of an AIR app installed.

private function onLoadComplete(event:Event):void
{
    // ignore xml declaration
    var str:String = URLLoader(event.target).data as String;
    var index:int = str.indexOf('<update');
    str = str.substr(index, str.length);

    // convert String to XML
    var remoteAppXML:XML = XML(str);
    var ns:Namespace = remoteAppXML.namespace();

    // get new version number
    var version:String = remoteAppXML.ns::version;

    // get current version number
    var appXML:XML = NativeApplication.nativeApplication.applicationDescriptor;
    var ns:Namespace = appXML.namespace();
    currentVersion = appXML.ns::version;

    if(currentVersion != version)
    {
        // download AIR file
    }
}

3. Download and save the AIR file. Don’t forget to call Updater.update() function.

public class UpdateAppCommand extends SimpleCommand implements ICommand
{
    override public function execute(note:INotification):void
    {
        // download updated .air file
        urlStream = new URLStream();
        fileData = new ByteArray();
        urlStream.addEventListener(Event.COMPLETE, loaded);
        urlStream.load(
            new URLRequest('http://mariusht.com/files/products/notelist/NoteList.air'));
    } 

    private function loaded(event:Event):void
    {
        urlStream.readBytes(fileData, 0, urlStream.bytesAvailable);
        writeAirFile();
    } 

    private function writeAirFile():void
    {
        var file:File = File.applicationStorageDirectory.resolvePath('NoteList.air');
        var fileStream:FileStream = new FileStream;
        fileStream.open(file, FileMode.WRITE);
        fileStream.writeBytes(fileData, 0, fileData.length);
        fileStream.close();

        var versionProxy:VersionProxy =
            facade.retrieveProxy(VersionProxy.NAME) as VersionProxy;
        var updater:Updater = new Updater;
        updater.update(file, versionProxy.version);
    } 

    private var urlStream:URLStream;
    private var fileData:ByteArray;

Related Links:
Updating AIR applications (Adobe AIR 1.5 LiveDocs)

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute"
    creationComplete="init()" viewSourceURL="srcview/index.html"> 

    <mx:Script>
        <![CDATA[
            private function init():void
            {
                nativeApplication.idleThreshold = 20;
                nativeApplication.addEventListener(Event.USER_IDLE, userIdleHandler);
                nativeApplication.addEventListener(Event.USER_PRESENT, userPresentHandler);
            } 

            private function userIdleHandler(event:Event):void
            {
                trace('idle');
            } 

            private function userPresentHandler(event:Event):void
            {
                trace('present');
            }
        ]]>
    </mx:Script> 

</mx:WindowedApplication>

Now it’s time to learn more advanced stuff: auto select for new created item. This would be very easy to accomplish with List control. You would probably use ArrayCollection as a dataProvider, call addItem(item:Object), keep track of that item index, and then use list.selectedIndex = index. 

Unfortunately this is not easy with Tree control. Tree control could have opened and closed nodes. If the nodes in the tree control are collapsed, the selectedIndex is different than when all the nodes are expanded. Instead of using selectedIndex you want to loop through all nodes to find a new item’s index.

Get Flex Builder for free if you are an unemployed developer

<?xml version="1.0" encoding="utf-8"?>
<mx:Application
    xmlns:mx="http://www.adobe.com/2006/mxml"
    layout="absolute"
    creationComplete="onCreationComplete()" viewSourceURL="srcview/index.html"> 

    <mx:Script>
        <![CDATA[
            import mx.collections.XMLListCollection;
            [Bindable]
            private var company:XML =
              <node>
                <node label="Finance" code="200">
                    <node label="John H"/>
                    <node label="Sam K"/>
                </node>
                <node label="Operations" code="400">
                    <node label="Bill C"/>
                    <node label="Jill W"/>
                </node>
                <node label="Engineering" code="300">
                    <node label="Erin M"/>
                    <node label="Ann B"/>
                </node>
              </node>;

            [Bindable]
            private var companyData:XMLListCollection = new XMLListCollection(company.children());

            private function removeNode():void
            {
                var node:XML = XML(tree.selectedItem);
                if(node == null) return;

                var children:XMLList = XMLList(node.parent().children());
                for(var i:int=0; i<children.length(); i++)
                {
                    if(children[i].@label == node.@label)
                    {
                        delete children[i];
                    }
                }
            } 

            private function addNode():void
            {
                var node:XML = <node/>;
                node.@label = folderNameInput.text;

                var parentNode:XML;
                if(tree.selectedItem == null)
                    companyData.addItem(node);
                else
                {
                    parentNode = XML(tree.selectedItem);
                    parentNode.appendChild(node);
                    tree.expandItem(parentNode, true);
                }
                folderNameInput.text = '';
                selectNode(node);
            } 

            private var _index:int;
            private var _isFounded:Boolean = false;
            private function selectNode(node:XML):void
            {
                _isFounded = false;
                _index = -1;
                for each(var parentNode:XML in companyData)
                {
                    if(tree.isItemOpen(parentNode))
                        loopAndFindXml(node, parentNode);
                    else if(!_isFounded)
                        _index++;
                }
                tree.selectedIndex = _index;
            } 

            private function loopAndFindXml(node:XML, parentNode:XML):void
            {
                if(_isFounded)
                    return;
                _index++;
                //trace('myNode , '+_index+' , '+parentNode.toXMLString());

                for(var i:int=0; i<parentNode.children().length(); i++)
                {
                    if(_isFounded)
                        return;

                    if(tree.isItemOpen(parentNode.node[i]))
                    {
                        //trace('loop');
                        loopAndFindXml(node, parentNode.node[i]);
                    }
                    else
                    {
                        if(_isFounded)
                            return;
                        _index++;
                        //trace('myNode1 '+_index+' , '+parentNode.node[i].toXMLString());

                        if(parentNode.node[i] == node)
                        {
                            //trace('found');
                            _isFounded = true;
                            return;
                        }
                    }
                }
            } 

            private function expandAllTreeNodes(tree:Tree):void
            {
                tree.expandChildrenOf(company, true);
            } 

            private function onCreationComplete():void
            {
                expandAllTreeNodes(tree);
            } 

        ]]>
    </mx:Script> 

    <mx:Tree id="tree"
        x="8" y="40"
        dataProvider="{companyData}"
        labelField="@label"
         width="162" height="245"
    /> 

    <mx:TextInput id="folderNameInput"
        x="10" y="11"
    /> 

    <mx:Button
        x="178" y="11"
        label="Add Node"
        width="112"
        click="addNode()"
    /> 

    <mx:Button
        x="178" y="41"
        label="Remove Node"
        click="removeNode()"
     width="112"/> 

</mx:Application>

View the Live Demo (right click to view the source)

Any thoughts on this?

Above Problem Solved. (Updated)

Read the Flex 3.3 SDK
http://www.adobe.com/support/documentation/en/flex/3/releasenotes_flex3_sdk.html

You need to:
1. Download Flex SDK zip file.
2. Uninstall current Flash Player.
3. Install Flash Player from /runtimes/player/10/win/

Thanks to the Flex Community(Michael Borbor).

In this example i want to show you how to download remote image(jpg or png) and save it to the desktop.

Load remote file. We use Loader Class and listen for complete event. We call load method and pass URLRequest parameter.

private function loadRemoteImage(url:String):void
{
    var loader:Loader = new Loader();
    loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
    loader.load(new URLRequest(url));
}

Create a BitmapData object. We can access BitmapData object through Bitmap object. In our example Bitmap object is the same as loaderInfo.content.

FOR DEMO PURPOSES ONLY: Image (<mx:Image id=”img”/>) component shows downloaded image.

private function completeHandler(event:Event):void
{
    var loaderInfo:LoaderInfo = event.target as LoaderInfo;
    img.source = loaderInfo.content;
    var bitmap:Bitmap = loaderInfo.content as Bitmap;
    _bitmapData = bitmap.bitmapData;
}

Encode image to JPEG or PNG. Before saving image, we have to take the current BitmapData object and encode to the ByteArray object. This ByteArray object needs to be encoded in the proper format and for this we can use the JPEGEncoder and PNGEncoder. 

private function saveImage():void
{
    var imgByteArray:ByteArray;
    var extension:String;
    if(textInput.text.toLowerCase().indexOf('.jpg') != -1)
    {
        // encode to JPEG
        var jpegEncoder:JPEGEncoder = new JPEGEncoder(80);
        imgByteArray = jpegEncoder.encode(_bitmapData);
        extension = '.jpg';
    }
    else if(textInput.text.toLowerCase().indexOf('.png') != -1)
    {
        // encode to PNG
        var pngEncoder:PNGEncoder = new PNGEncoder();
        imgByteArray = pngEncoder.encode(_bitmapData);
        extension = '.png';
    }
    else
        return;

    ...

Save file to the desktop. Now that we already have the encoded ByteArray, we just need to save it to a local file. We do this using the File and FileStream classes.

     ...
     var file:File = File.desktopDirectory.resolvePath('test'+extension);
     var fileStream:FileStream = new FileStream();
     fileStream.open(file, FileMode.WRITE);
     fileStream.writeBytes(imgByteArray);
     fileStream.close();
}

View Full Source Code

Each file is about 4MB, 2639×3949 pixels. Download posters(zip file)

You can order a set of Flex, AIR, and ActionScript posters(2 feet by 3 feet) from Adobe website.

NOTE: you need to have an Adobe ID and a valid Flex 3 serial number to order them

PDF versions appeared again on http://flex.org/poster/posters.zip